Первые шаги в автоматизации OpenOffice.Calc и OpenOffice.Writer под Delphi

Введение

   О чем эта статья?
   Статья эта - живой пример и краткий учебник по автоматизации OpenOffice.Calc и OpenOffice.Writer. Дело в том, что в большинстве организаций используются различные специфические программы. Однако, для форматирования результатов их работы применяются продукты компании Microsoft (в частности, Excel и Word). То есть результаты работы специфической программы передаются в программы из пакета Microsoft Office, а затем их можно, например, распечатать и включить в отчет. Ситуация знакомая многим. Причем средства взаимодействия с программами фирмы Microsoft хорошо изучены и давно используются. Однако не стоит забывать, что эти программы являются платными, и не каждая организация способна выложить круглую сумму за оснащение всех своих ПК лицензионными версиями этих программ. Поэтому в организации, где я работаю и была поставлена задача сделать все аналогично, но под бесплатный продукт OpenOffice. Собственно, это было короткое введение, теперь перейдем к основной части.

   Основное требование заключалось в том, чтобы написано все было на Delphi. Сразу появилась проблема: материалов по OpenOffice под Delphi в сети почти нет. Основной документ, которым стоит обзавестись начинающему разработчику - безусловно DevelopersGuide по OpenOffice. В этом документе можно найти ответы почти на все возникающие в процессе разработки вопросы.

   Определившись с тем, откуда лучше черпать информацию, разберемся, что именно мы хотим получить от готового решения. В большинстве случаев для успешной совместной работы офисных программ и программ конкретного предприятия необходимо наличие следующих действий:
   1. Создать новый файл (как вариант, открыть существующий файл).
   2. Сохранить изменения в файле.
   3. Вывести файл на печать.
   4. Закрыть документ.
   5. Внести в открытый документ какие-либо изменения.
   6. Отформатировать документ (имеется в виду изменение цвета фона, размера шрифта, стили шрифта и т.д.).

   Начнем со всего по порядку, причем, я постараюсь описать все так, как я сам разбирался с проблемами, соответственно, некоторые методы, написанные позже всего, дублируют по функциональным возможностям методы, написанные ранее, однако, настоятельно рекомендую знакомиться с предложенным материалом именно в этом порядке, так как это будет проще для понимания.

Часть первая. Начало

   Начнем, как это водится, с основ. В основе OpenOffice лежит компонентная модель UNO (Universal Network Objects). Которая обеспечивает возможности для работы OpenOffice на базе различных платформ. Сразу оговорюсь, что мы разрабатываем приложение под ОС Windows, то есть с помощью технологии OLE, которая не поддерживается напрямую OpenOffice. Связано это с тем, что OLE - все-таки Windows технология, а, как было сказано выше, OpenOffice - продукт кроссплатформенный.

   Для взаимодействия между OLE и языком OpenOffice используется технология Automation Bridge. Модель UNO, в свою очередь, предоставляет возможность работы со своими компонентами через Service Manager.

   Данная информация дана просто в качестве вводной, так как эти вопросы уже многократно обсуждались и, как мне кажется, не нуждаются в дополнительном освещении с моей стороны.

Часть вторая. Основы

2.1 Подключение к серверу автоматизации

   Для начала работы с OpenOffice нам нужно подключиться к серверу автоматизации. Как это сделать, показано в листинге 1. Отмечу, что переменные OO и Document объявлены как Variant.
 

Листинг 1

function TOpenOffice.Connect: boolean;
begin
   if VarIsEmpty(OO) then
      OO := CreateOleObject('com.sun.star.ServiceManager');
   Result := not (VarIsEmpty(OO) or VarIsNull(OO));
end;

2.2 Отключение от сервера автоматизации

   Рассмотрим теперь функцию Disconnect. Она еще проще (листинг 2).
 

Листинг 2
procedure TOpenOffice.Disconnect;
begin
   OO := Unassigned;
end;

   Теперь можно работать с документами, только для начала надо создать или открыть существующий.

2.3 Создание нового документа

   Для создания документа используем функцию CreateDocument. Она приведена на листинге 3.
 

Листинг 3
function TOpenOffice.CreateDocument: boolean;
var
   Desktop: Variant;
begin
   Desktop := OO.createInstance('com.sun.star.frame.Desktop');
   Document := Desktop.LoadComponentFromURL(
                  'private:factory/swriter', '_blank', 0,
                  VarArrayCreate([0, -1], varVariant));
   Result := not (VarIsEmpty(Document) or VarIsNull(Document));
end;

2.4 Открытие документа

   Теперь функция открытия документа. Сама функция приведена на листинге 4.
 

Листинг 4
function TOpenOffice.OpenDocument(const FileName:string):
                                                     boolean;
var
 Desktop: Variant;
 VariantArray: Variant;
begin
 Desktop := OO.CreateInstance('com.sun.star.frame.Desktop');
 VariantArray := VarArrayCreate([0, 0], varVariant);
 VariantArray[0] := MakePropertyValue('FilterName',
                                                'MS Word 97');
 Document := Desktop.LoadComponentFromURL(FileName, '_blank',
                                                0,VariantArray);
 Result := not (VarIsEmpty(Document) or VarIsNull(Document));
end;

   Небольшое отступление. Возникает вопрос: почему мы открываем файлы MS Office? Ответ прост. Пользователь не зависит от ПО, установленного у него на компьютере, ведь легко представить себе ситуацию, когда на одном компьютере установлен OpenOffice, а на другом MS Office. Поэтому работа с файлами одного формата решит проблему взаимодействия пользователей, у которых стоят различные "офисы". Более того, конечный пользователь даже не заметит разницы: оболочки очень похожи, функции выполняются одинаковые. Как мне кажется, это является важным условием при переходе с MS Office на OpenOffice.

   В этой функции используется функция MakePropertyValue. Листинг 5.
 

Листинг 5
function TOpenOffice.MakePropertyValue(PropertyName,
                                PropertyValue:string):variant;
var
 Structure: variant;
begin
 Structure :=
       OO.Bridge_GetStruct('com.sun.star.beans.PropertyValue');
 Structure.Name := PropertyName;
 Structure.Value := PropertyValue;
 Result := Structure;
end;

2.5 Процедуры "Сохранить документ" и "Сохранить как"

   Теперь рассмотрим сохранение документа в формате MS Word (или Excel).
   Процедура сохранения показана на листинге 6.
 

Листинг 6

procedure TOpenOffice.SaveDocument(const FileName:String);
var
  Desktop: Variant;
  VariantArray: Variant;
begin
  Desktop := OO.createInstance('com.sun.star.frame.Desktop');
  VariantArray := VarArrayCreate([0, 0], varVariant);
  VariantArray[0] :=
              MakePropertyValue('FilterName', 'MS Word 97');
  Document.StoreToURL(FileName, VariantArray);
end;

   Рассмотрим еще одну процедуру SaveAs. Эта процедура просто сохраняет документ под новым именем (листинг 7).
 

Листинг 7
procedure TOpenOffice.SaveAs(FileName: String);
const
   Bounds:array[1..2] of integer = (0,1);
var
   VariantArray: Variant;
begin
 VariantArray := VarArrayCreate([0,1], varVariant);
 VariantArray[0] :=
          MakePropertyValue('FilterName', 'MS Excel 97');
 VariantArray[1] := MakePropertyValue('Overwrite', True);
 Document.storeToURL('file:///'+FileName, VariantArray);
end;

2.6 Закрытие документа

   Следующая процедура - закрытие текущего документа. Она тоже проста и не требует никаких комментариев (листинг 8).
 

Листинг 8

procedure TOpenOffice.CloseDocument();
begin

 Document.Close(True);
 Document:=Unassigned;
end;

   Последняя процедура в этом разделе - процедура вывода на печать текущего документа (листинг 9).
 

Листинг 9
procedure TOpenOffice.Print(iNumCopies:integer);
const Bounds:array[1..2] of integer = (0,0);
var
    VariantArray: Variant;
begin
 if ( iNumCopies < 1 ) or ( iNumCopies > 512 ) then
     iNumCopies := 1;
 VariantArray := VarArrayCreate(Bounds, varVariant);
 VariantArray[0]:= MakePropertyValue('CopyCount',iNumCopies);
 Document.print(VariantArray);
end;

   На этом мы закончим рассмотрение основных функций, необходимых для работы с OpenOffice и перейдем к работе непосредственно с документами.

3.1 Вставка текста в начало документа

   Основными действиями, которые нас интересуют в работе с Writer'ом является возможность вставлять текст, например в начало документа и по метке, плюс возможность задавать форматирование текста. Поскольку работа с метками несколько более сложная, разберемся вначале с первым вариантом. Функция вставки текста приведена в листинге 10.
 

Листинг 10
procedure TOpenOffice.InsertTextWriter(const Text: String);
var
   TextPointer: Variant;
   CursorPointer: Variant;
begin
   TextPointer := Document.GetText;
   CursorPointer := TextPointer.CreateTextCursor;

   TextPointer.InsertString(CursorPointer, Text, false);
   TextPointer.InsertControlCharacter(CursorPointer, 0, false);
end;

   Метод InsertControlCharacter вставляет символ завершения строки. Второй аргумент ("0") - константа, которая обозначает этот символ (com::sun::star::text::ControlCharacter::PARAGRAPH_BREAK).

   Теперь разберемся с форматированием текста. Чтобы поменять размер шрифта или его цвет, нужно установить соответствующее свойство курсора. Например, для установки 20 шрифта это будет выглядеть так:

CursorPointer.SetPropertyValue('CharHeight', 20);

   Можно поменять цвет шрифта:

CursorPointer.SetPropertyValue('CharColor', 500);

   В этом случае в качестве второго параметра передается цвет в формате RGB.

CursorPointer.SetPropertyValue('CharShadowed', True);

   Можно сделать текст подчеркнутым, курсивным и жирным. Это будет выглядеть так:

CursorPointer.setPropertyValue('CharPosture',fsItalic);
CursorPointer.setPropertyValue('CharWeight',fsBold);
CursorPointer.setPropertyValue('CharUnderline',fsUnderline);

   В принципе, можно и самому задать степень "жирности" и другие параметры. Ведь fsBold и т.д. есть ни что иное, как константы. Поэтому можно, например ввести вместо fsBold константу 200, текст будет жирными. Советую поэкспериментировать с этим.

   Отмечу, что вновь вставленная строка будет обладать установленными свойствами, если их определить до вставки.

   И еще пара возможностей для работы с курсором. Можно перейти в начало текста:

CursorPointer.gotoStart(False).

   В конец текста:

CursorPointer.gotoEnd(False).
CursorPointer.goLeft(short Count, boolean Expand) - передвигаем курсор влево на Count.
Аналогично goRight(short Count, boolean Expand).

   Можно передвигаться по словам:

boolean gotoNextWord(boolean Expand);
boolean gotoPreviousWord(boolean Expand);
boolean gotoEndOfWord(boolean Expand);
boolean gotoStartOfWord(boolean Expand);

   Переменная Expand определяет будет ли курсор расширятся при своем передвижении.

   Существует и множество других возможностей работы с курсором, но мы остановимся только на этом необходимом наборе.

3.2 Вставка текста по метке

   Теперь рассмотрим вставку текста по меткам. Вообще, на мой взгляд, именно операции с метками являются самыми важными с точки зрения автоматизации работы на предприятии. Обычно создается типичный шаблон отчета, туда один раз забиваются все метки и все. Дальнейшая работа программ автоматизации каждый раз вставлять новые данне в этот шаблон по меткам. Поэтому отведем работе с метками повышенное внимание. За работу с метками отвечает интерфейс xBookmarksSupplier. В листинге 11 показан пример вставки текста по метке.
 

Листинг 11
procedure TOpenOffice.InsertTextByNameWriter(const Text: String,
                                          BookmarkName: String );
var
 TextPointer: Variant;
 CursorPointer: Variant;
 BookmarksSupplier: Variant;
 Bookmark: Variant;
 Flag: boolean;
begin
 Flag:=True;
 TextPointer := Document.GetText;
 CursorPointer := TextPointer.CreateTextCursor;
 BookmarksSupplier:=Document.getBookmarks;
 try
  Bookmark:=BookmarksSupplier.getByName(BookmarkName).getAnchor;
 except
  ShowMessage('Такой метки нет');
  Flag:=False;
 end;
 if(Flag)
 then Bookmark.setString(Text);
end;

4.1 Основы работы с OpenOffice.Calc

   Для того, чтобы начать работу с документом Calc, по аналогии с Writer'ом надо получить указатели вначале на листы, потом на конкретный лист и только потом на ячейку или диапазон ячеек. Таким образом, схема взаимодействия такова: ServiceManager -> Desktop -> Document -> Sheets -> Sheet -> Cell (Cells).

   Получить все листы можно таким образом:

Sheets := Document.GetSheets

   Сделать это можно, например, при открытии файла. Отмечу, что переменные Sheets, Sheet, Cell объявлены как Variant.
   После того, как мы получили указатель на все листы, надо получить указатель на конкретный лист. Сделать это можно либо по его индексу:

Sheet := Sheets.getByIndex(Index);

   либо по имени:

Sheet := Sheets.getByName('Sheet_Name').

   Определим процедуру, которая устанавливает текущий лист по его индексу (листинг 12).
 

Листинг 12
procedure TOpenOffice.GetSheet(const Index :Word);
begin
   Sheet := Sheets.getByIndex(Index);
end;

   Теперь можно получать указатель на конкретную ячейку или группу ячеек и работать с ними. Для записи данных в ячейку есть три метода, название которых говорит само за себя:

   1. setValue;
   2. setString;
   3. setFormula.

   Соответственно, первый вставляет число, второй - строку, третий - формулы. Чтобы получить значение, которое храниться в ячейке, надо в начале определить ее тип с помощью метода Cell.getType. Результатом работы будет одно из следующих значений:

   1.0 - ячейка пуста;
   2.1 - в ячейке число;
   3.2 - строка;
   4.3 - формула.

   После этого можно узнать значение, для этого в зависимости от результата работы метода getType надо вызвать методы соответственно: getValue, getString, getFormula.

   Единственное, что мы не сделали - не получили указатель на ячейку. Сделать это можно несколькими способами, в зависимости от цели. В листинге 13 приведен пример записи в ячейку текста, ячейка задается своими координатами.
 

Листинг 13
procedure TOpenOffice.InsertTextByCoord(const Text: String;
                                      col:integer; row:integer);
begin
   Cell := Sheet.getCellByPosition(col, row);
   Сell.setString(Text);
end;

Cell := Sheet.getCellByPosition(col, row).

   Потом записываем в эту ячейку текст.

4.3 Запись в ячейку по метке

   Разобравшись с простым, перейдем к главному - работе с метками. Некоторые основы мы уже разобрали при работе с Writer'ом. Теперь будет легче. В листинге 14 приведен пример вставки текста в ячейку, которая задается меткой.
 

Листинг 14
procedure TOpenOffice.InsertTextByName(const Text: String;
                                                    Name: String);
var
   i:boolean;
   j:integer;
   Perem :longint;
begin
   Perem:=0;
   Perem:=Sheets.getCount;
   j:=0;
   repeat
      i:=True;
      Sheet := Sheets.getByIndex(j);
      try
         Sheet.getCellRangeByName(Name);
      except
         j:=j+1;
         i:=False;
         Perem:=Perem-1;
      end;
   until (i or (Perem=1));
   if(Perem=1) then ShowMessage('Нет такой метки')
   else
      begin
         Cell:=Sheet.getCellRangeByName(Name);
         Cell.setString(Text);
       end;
end;

try
  Sheet.getCellRangeByName(Name).

   Если метки нет, то мы просто устанавливаем активным следующий лист и проверяем дальше пока не найдем такую метку или пока поймем, что такой метки нет (тогда выдается сообщение об ошибке). Если мы эту метку найдем, то записываем туда текст:

Cell.setString(Text).

   На этом работа этой функции заканчивается.

4.4 Запись массива в диапазон ячеек

   Теперь будем работать с группой ячеек. Для примера рассмотрим вставку массива из четырех элементов в группу из четырех ячеек. Процедура приведена в листинге 15.
 

Листинг 15
procedure TOpenOffice.InsertTableByName(Text1:String;
         Text2:String; Text3:String; Text4:String; Name:String);
const Bounds:array[1..4] of integer = (1,2,1,2);
var
   VariantArray:Variant;
   i:boolean;
   j:integer;
   Range: Variant;
   Perem :longint;
begin
   VariantArray := VarArrayCreate(Bounds, varVariant);
   Perem:=0;
   Perem:=Sheets.getCount;
   VariantArray[1,1]:=Text1;
   VariantArray[1,2]:=Text2;
   VariantArray[2,1]:=Text3;
   VariantArray[2,2]:=Text4;
   j:=0;
   repeat
      i:=True;
      Sheet := Sheets.getByIndex(j);
      try
         Sheet.getCellRangeByName(Name);
      except
         j:=j+1;
         i:=False;
         Perem:=Perem-1;
      end;

   until (i or (Perem=1));
   if(Perem=1) then ShowMessage('Нет такой метки')
   else
      begin
          Range:=Sheet.getCellRangeByName(Name);

          Range.setDataArray(VariantArray);
       end;
end;

VariantArray := VarArrayCreate(Bounds, varVariant);
VariantArray[1,1]:=Text1;
VariantArray[1,2]:=Text2;
VariantArray[2,1]:=Text3;
VariantArray[2,2]:=Text4;

   Разница есть в методе записи массива. Делается это с помощью метода setDataArray. Аргументом этого метода является ранее созданный массив из четырех элементов.

4.5 Форматирование группы ячеек

   Теперь рассмотрим функцию форматирования группы ячеек (листинг 16).
 

Листинг 16
procedure TOpenOffice.RangeFormat(Name:String; FontName:String;
       FontSize, FontType, FontColor, BackColor:longint);
var
 font: TFont;
 Range: Variant;
begin
   Range:=GetRange(Name);
   if FontName <> '' then Range.charFontName:=FontName;
   if FontSize <> 0 then Range.charHeight:=FontSize;
   if FontType <> -1 then
      begin
         if(FontType and $04)=4 then
            Range.charWeight:=fsBold else
            Range.charWeight:=0;
         if(FontType and $02)=2 then
            Range.charPosture:=fsItalic else
            Range.charPosture:=0;
         if(FontType and $01)=1 then
            Range.charUnderline:=fsUnderline else
            Range.charUnderline:=0;
      end;
      if FontColor <> -1 then
         Range.charColor:=FontColor;
      if BackColor <> -1 then
         Range.cellBackColor:=BackColor;
end;

   После получения указателя на диапазон ячеек мы проверяем параметры и устанавливаем новые свойства для этого диапазона. Если мы ввели новое имя шрифта, тогда мы устанавливаем этот шрифт для диапазона ячеек Name с помощью метода charFontName:

Range.charFontName:=FontName

   Точно также устанавливаем новый размер шрифта с помощью метода charHeight:

Range.charHeight:=FontSize;

   Теперь рассмотрим установку FontType. Вариантов значения параметра FontType может быть всего 8.

   1.0 - тогда шрифт остается стандартным;
   2.1 - тогда шрифт подчеркнутый;
   3.2 - курсив;
   4.3 - подчеркнутый + курсив;
   5.4 - жирный;
   6.5 - жирный + подчеркнутый;
   7.6 - жирный + курсив;
   8.7 - жирный + подчеркнутый + курсив.

   Таким образом, мы делаем побитовую конъюнкцию FontType с константами 1, 2 и 4 и определяем тип шрифта, который нужно установить. Например, курсив устанавливаем так:

Range.charPosture:=fsItalic.

   С цветом шрифта и цветом фона поступаем аналогично, за их установку отвечают методы CharColor и CellBackColor:

Range.charColor:=FontColor
Range.cellBackColor:=BackColor
 

Листинг 17
function TOpenOffice.GetRange(Name: String): Variant;
var
   i: integer;
   Sheet: Variant;
begin
   for i := 0 to Sheets.getCount - 1 do
   try
        Sheet  := Sheets.getByIndex( i );
        Result := Sheet.getCellRangeByName( Name );
        if not ( VarIsEmpty(Result) or VarIsNull(Result)) then
        Exit;
   except
     Result := Null;
   end;
end;

   В заключении хочу отметить, что, конечно, то что мы рассмотрели не является избыточным. Однако, очень хочется верить, что пригодится многим, желающим самостоятельно начать рассматривать OpenOffice и делающих первые шаги в его автоматизации. В принципе, приведенных выше сведений с лихвой хватит для написания своего класса, который бы выполнял некоторые задачи, характерные для деятельности конкретной организации. Если же этих сведений не хватит, тогда Developer's Guide и форум разработчиков ждут вас!

   Что касается моей организации, то переход от Excel к OpenOffice был сделан. Чтобы полностью не отказываться от Excel была написана виртуальная функция, которая проверяла наличие на компьютере пользователя установленного OpenOffice, если он был найден, программа работала с классом автоматизации OpenOffice, в противном случае - работала с классом Excel.

   От себя могу добавить, что поработав с OpenOffice я был приятно удивлен возможностями этого пакета. Честно говоря, такой функциональности получить от бесплатного пакета я не ожидал! Поэтому настоятельно вам советую поиграться в эти игры - оно того стоит!

• Обратиться в "Интерфейс" за дополнительной информацией/по вопросу приобретения продуктов
• Подробнее о продуктах Embarcadero / CodeGear
• Курсы обучения по продуктам компании Embarcadero/CodeGear
• Купить продукты компании Embarcadero Technologies в интернет-магазине itshop.ru
• Скачать демоверсии продуктов компании Embarcadero / CodeGear